Holarch

指南 · SysML v2

将 SysML v1 模型迁移到 SysML v2:分步迁移

SysML v1 模型可以自动转换为 SysML v2,但迁移不仅仅是文件转换:必须有人决定转换后的模型应该是什么样子,并检查它是否仍然表达了 v1 模型所表达的内容。本指南分八个步骤介绍一次迁移,从清点 v1 模型到完成切换,并逐行转换和解读一个小模型。

本页内容
  1. 开始之前:这是翻译,而不是升级
  2. 1. 清点 v1 模型
  3. 2. 从 SysML v1 工具导出模型
  4. 3. 转换试点包
  5. 4. 阅读转换报告
  6. 实例:一个小型漫游车模型
  7. 5. 返工被近似转换或未包含的内容
  8. 6. 重建重要的视图
  9. 7. 检查和评审 v2 模型
  10. 8. 转换其余部分并完成切换
  11. 迁移检查清单
  12. 后续阅读

开始之前:这是翻译,而不是升级

SysML v2 是一门新语言,而不是 SysML v1 文件格式的新版本。块变为部件定义,端口以端口定义为类型,需求带有条件,图变为由模型定义的视图。SysML v1 与 v2 逐一解释了这些差异。

转换器完成机械性的部分:凡是在 SysML v2 中有对应项的元素都以 SysML v2 写出,其余的则在报告中列出。转换器无法替您决定团队希望如何使用这门新语言。应将迁移规划为一项建模任务,有负责人、有评审,并有一个让 v2 模型成为参考的时间点。

本指南使用 Holarch 的转换器,它将 SysML 1.x 模型导入 SysML v2 项目,并将每个元素报告为已转换、近似转换或未包含。无论您使用哪种转换器,这些规划步骤都适用。

1. 清点 v1 模型

在导出任何内容之前,先弄清模型包含什么以及谁依赖它。一份简短的清单可以减少以后的返工。

  • 包和负责人。列出顶层包、每个包由谁维护,以及哪些包被其他模型或文档引用。包是您进行转换和评审的单位。
  • 重要的图。记下人们在评审和文档中实际使用的图。图的布局不会迁移到 SysML v2,因此这些图会成为需要重建的视图。
  • 配置文件和构造型。列出您自己的构造型及其标记值。它们会变为元数据定义,其在新模型中的含义需要重新商定。
  • 以代码编写的行为。以 OCL、动作语言或工具脚本编写的不透明行为、守卫和约束,会以原始语言的文本形式保留;它们不会被翻译。
  • 未命名的元素。指向未命名元素的关系无法用 SysML v2 文本编写,因为 SysML v2 文本按名称引用元素。现在就在 v1 工具中为您追溯到的元素命名。
  • 规模。Holarch 每次转换一个文件,最大 64 MB、250,000 个元素。更大的模型按包逐个导出。

2. 从 SysML v1 工具导出模型

转换器从 XMI 读取模型,XMI 是 SysML v1 工具写出的交换格式。每种工具导出的方式略有不同:

工具导入什么
Cameo Systems Modeler、MagicDraw.mdzip 项目文件,或通过 File → Export To → Eclipse UML2 (v5.x) XMI File 导出的 .xmi 文件
Enterprise Architect选择包,Publish → Export XML,选择 XMI 2.1,然后导入 .xml 文件。不直接读取项目文件(.eap、.qea)。
IBM Rhapsody通过 XMI 工具包导出的 XMI 2.x
Eclipse Papyrus模型的 .uml 文件

将导出的文件与迁移记录一起保存:它是您的评审所依据的确切 v1 输入。

3. 转换试点包

从一个有代表性但不是最大的包开始:一个包含结构、接口、一些行为及其需求的子系统。试点会在您让整个团队投入之前,展示您的模型转换后的样子。

  1. 创建一个 SysML v2 项目,或打开转换后的模型要放入的项目,然后点击模型 → 导入和导出。
  2. 在导入下,试点时选择导入到新的 SysML v2 项目,这样不会影响其他任何内容。
  3. 将导出的文件拖放到框中。进度卡片显示各个阶段:读取 XMI 文件、转换为 SysML v2、检查结果。

此时尚未导入任何内容。下一个界面是带有转换报告的预览。

4. 阅读转换报告

预览顶部的从 SysML v1 转换给出已转换、近似转换和未包含的元素数量,以及 SysML v2 文本检查是否没有问题。v1 模型的每个元素都有一个结果:

  • 已转换:该元素在 SysML v2 中有直接对应项,例如块变为 part def。
  • 近似转换:该元素以改变后的形式保留,例如经过选择节点的转换变为每条路径一个转换。这些地方的含义可能与 v1 模型不同。
  • 未包含:SysML v2 中没有对应项,或该元素指向文件中不存在的内容。

使用显示列出近似转换和未包含的元素。每一行给出元素、其 SysML v1 类型、它变成了什么及其 SysML v2 名称,以及原因。打开显示 SysML v2 文本阅读结果,点击下载报告将报告保存为 CSV 文件。CSV 就是第 5 步的工作清单:按原因排序,并为每一组指定负责人。

实例:一个小型漫游车模型

一个小型 SysML v1 模型,描述行星漫游车的电源路径,分为三个包:

包SysML v1 元素
Types一个单位为 W 的值类型 Power;一个块 Charge;一个接口块 Power Interface,带有两个输出流属性 charge(类型为 Charge)和 voltage(类型为 Real)
结构一个封装块 Rover,带有部件属性 battery 和 computer、值为 120 W 的值属性 power budget、连接它们端口的连接器 power bus,以及其上传递 Charge 的项流 power flow。一个带有代理端口 out 的块 Battery;一个带有共轭代理端口 in 和完整端口 raw 的块 Computer。两者都带有用户构造型 «Hardware» 及其标记值。一个其端由关联本身拥有的关联。
需求需求 R-1 Mission 和 R-2 Power Margin;R-2 派生自 R-1;R-2 由 battery 部件满足;一个从 Computer 到 Battery 的 trace

转换后的结果如下。该清单是转换器的原始输出,未作改动:

package 'Rover Model' {
  package Types {
    attribute def Power :> ISQ::PowerValue;
    part def Charge;
    port def 'Power Interface' {
      out item charge : Charge;
      out attribute voltage : ScalarValues::Real;
    }
  }
  package Structure {
    part def Rover {
      doc /* Six-wheeled science rover. */
      @SysMLv1Library::BlockData { isEncapsulated = true; }
      part battery : Battery;
      part computer : Computer;
      attribute 'power budget' : Types::Power = 120 [SI::W];
      connection 'power bus' connect battery.'out' to computer.'in';
      satisfy Requirements::'Power Margin' by battery;
      flow 'power flow' of Types::Charge from battery.'out' to computer.'in';
    }
    part def Battery {
      @'SysML v1 Profiles'::rov::Hardware { qualified = "true"; vendor = "Acme Cells"; }
      port 'out' : Types::'Power Interface';
      attribute capacity : Types::Power;
    }
    part def Computer {
      @'SysML v1 Profiles'::rov::Hardware { vendor = "Orbital Logic"; }
      port 'in' : ~Types::'Power Interface';
      part raw : Types::Charge {
        @SysMLv1Library::PortData { isFullPort = true; }
      }
    }
  }
  package Requirements {
    requirement <'R-1'> Mission {
      doc /* The rover shall explore the landing site. */
    }
    requirement <'R-2'> 'Power Margin' {
      doc /* Keep a 50 % power margin. */
    }
    connection : DerivationConnections::Derivation connect 'Power Margin' to Mission;
    dependency from Structure::Computer to Structure::Battery {
      @SysMLv1Library::TraceData { isTrace = true; }
    }
  }
}

package 'SysML v1 Profiles' {
  package rov {
    metadata def Hardware {
      attribute qualified : ScalarValues::String;
      attribute vendor : ScalarValues::String;
    }
  }
}

v1 模型各部分的转换结果:

  • 带单位的值类型。以瓦特为单位的 Power 特化标准库的 ISQ::PowerValue,默认值连同其单位写出:120 [SI::W]。单位不属于已映射 SI 单位的值类型保持为实数,单位写在其文档中,并报告为近似转换。
  • 块和属性。块变为 part def,部件属性变为 part。块的 isEncapsulated 没有对应的 SysML v2 关键字,因此作为 SysMLv1Library::BlockData 元数据保留。
  • 接口块和端口。接口块变为 port def,其流属性成为有方向的特征:以块为类型的流属性变为 out item,值流属性变为 out attribute。共轭代理端口的类型为 ~Types::'Power Interface'。完整端口变为带有 SysMLv1Library::PortData 元数据的部件,因为 SysML v2 端口以端口定义为类型。
  • 连接器和项流。连接器变为两个端口之间的 connection,其上的项流变为相同端口之间传递 Charge 的 flow。
  • 需求。每条需求将其 id 保留为简称 <'R-1'>,将其文本保留为 doc。satisfy 关系位于拥有满足部件的块中;derive 关系变为派生连接;trace 变为带有 SysMLv1Library::TraceData 的依赖关系。
  • 用户构造型。«Hardware» 变为包 'SysML v1 Profiles' 中的 metadata def,连同其标记值应用到每个块上。它的两次应用被报告为近似转换:无论标记值在配置文件中是什么类型,都变成了文本属性。
  • 关联。没有类的关联在这里没有 SysML v2 对应项,其由关联拥有的端也不会被转换。两者都报告为未包含;结构由块上的属性承载。

该模型的报告:31 个元素,27 个已转换,2 个近似转换,2 个未包含,文本检查无错误、无警告。不是普通标识符的名称,例如 'power budget' 或 'out'(一个 SysML v2 关键字),会加上引号,以保留其 v1 拼写。

5. 返工被近似转换或未包含的内容

按原因逐一处理报告中近似转换和未包含的行。大多数原因只需要在少数几种决定中做出选择:

报告的内容需要决定什么
端口的类型是一个非接口块的块;它变成了一个没有类型的端口定义一个包含跨越边界的特征的端口定义,并用它作为端口的类型。
经过选择、汇合点、分叉或汇合的转换;每条路径变成了一个转换检查合并后的守卫是否仍然表达 v1 图的本意;在路径现在更易读的地方加以简化。
触发器作为文档保留在含义清楚的地方,将变化触发器和时间触发器改写为 SysML v2 触发器,例如后接一段时长的 accept after。
单位不是 Holarch 映射的 SI 单位;值类型为实数决定是否有合适的标准量,或者保留实数和文档中的单位。
调用动作、不透明动作或接受动作以外的动作类型变成了普通动作用功能相同的 SysML v2 动作改写发送动作和其他特定动作。
活动分区未转换在部件中用 perform 说明哪个部件做什么,而不是使用泳道。
它指向一个未命名的元素在 v1 工具中为目标命名并重新转换,或在 v2 模型中添加该关系。
其名称在同一位置被使用了两次;已加后缀重命名为每个元素起一个能说明其是什么的名称。
标记值变成了元数据的文本属性为元数据属性指定所需的类型,并商定每个构造型现在的含义。

即使转换得很干净,也有两类文本需要查看。不透明主体以其原始语言的文本表示形式保留,例如 language "OCL" /* … */;Holarch 只检查以 SysML 或 KerML 编写的主体,因此在模型需要对守卫或约束求值的地方,应将其改写为 SysML 表达式。此外,逐字转换会保留 v1 中的变通做法,例如仅为设置某个值而创建的属性专用类型:在 SysML v2 中,这些只是用法上的普通重定义。需要重新思考的内容列出了常见的情况。

6. 重建重要的视图

图及其布局不会被转换。拿出第 1 步的图清单,为仍然需要的每张图创建一个视图:一般视图用于结构和需求,互连视图用于部件和连接,动作流视图用于活动,状态转换视图用于状态机。只重建人们实际使用的内容;其余一切无论如何都保存在模型中。参见视图参考。

7. 检查和评审 v2 模型

  • 文本检查干净。导入会在任何内容更改之前显示对转换后文本的检查;返工之后,编辑器会在您输入时标记任何新问题。
  • 数量一致。比较 v1 模型和 v2 模型之间的几个数字:需求、部件、端口、连接、验证关系。无法根据报告解释的差异值得一看。
  • 由使用模型的人评审。与负责人一起逐一检查试点包,从近似转换的元素和重建的视图开始。
  • 记录决定。写下您为端口、触发器、单位和构造型确定的建模模式,以便迁移的其余部分遵循它们。

8. 转换其余部分并完成切换

将其余的包逐个转换到同一个 SysML v2 项目中。每次导入都显示相同的预览:项目中已有的包显示为已更改或未更改,新包显示为新增,由您选择导入哪些包。每次导入是一个撤销步骤。

在 v2 模型完成评审之前,保留 v1 模型作为参考,然后将其冻结,并使 SysML v2 项目成为正式记录模型。从那时起,更改只进入 v2 模型。

迁移检查清单

  • 已列出包、负责人和重要的图。
  • 关系所指向的元素都有名称。
  • 导出的 XMI 文件已与迁移记录一起保存。
  • 试点包已转换,其报告已下载,并且每个近似转换和未包含的行都已有决定。
  • 已写下端口、触发器、单位和构造型的建模模式。
  • 所需的视图已重建;文本检查干净。
  • 模型的用户已评审试点。
  • 其余的包已用同样的方式转换,v1 模型已冻结。

后续阅读

Cameo Systems Modeler、MagicDraw、Enterprise Architect、Rhapsody 和 Eclipse Papyrus 是其各自所有者的商标。Holarch 与它们没有关联,也未获得它们的认可。